Como hacer un backup y restaurar la configuracion de Vista de carpetas en Windows 10

Windows imagen relacionada

El Explorador de archivos de Windows es fácil de navegar y viene con muchas características de accesibilidad interesantes, una de las cuales es la configuración de vista de carpetas.

Por ejemplo, si tiene una carpeta donde guardó solo videos, puede configurar la carpeta para que muestre miniaturas de los videos en lugar de una lista o detalles de archivo. También puede personalizar cada carpeta para mostrar íconos medianos, grandes o extragrandes.

Después de realizar estos cambios, es posible que desee realizar una copia de seguridad de ellos para restaurar la configuración de la vista de carpetas si se restablecen. Esta guía le muestra cómo hacer una copia de seguridad y restaurar la configuración de la vista de carpetas mediante un archivo por lotes.

Hacer una copia de seguridad y restaurar la configuración de Vista de carpetas en Windows 10

Siga los pasos a continuación para realizar una copia de seguridad y restaurar la configuración de Vista de carpetas en Windows 10.

  • Cree el archivo por lotes de copia de seguridad y restauración.
  • Desbloquee el archivo .bat si lo bloquea Windows.
  • Ejecute el archivo .bat para hacer una copia de seguridad y restaurar la configuración de vista de carpetas.

Cree el archivo por lotes de copia de seguridad y restauración

Haga clic en el botón Inicio y busque Bloc de notas . Seleccione la aplicación Bloc de notas de los resultados de la búsqueda para iniciarla.

Ingrese el siguiente texto en el nuevo archivo de Bloc de notas:

@ECHO OFF

title Backup and Restore Folder View Settings Tool

:choice

cls

echo.

echo OPTIONS:

echo.

echo 1. Back up your folder view settings.

echo 2. Restore folder view settings from backup.

echo 3. Cancel

echo.

echo.

set /P c=Type the option number you would like to do, and press Enter?

if /I "%c%" EQU "1" goto :verify1

if /I "%c%" EQU "2" goto :verify2

if /I "%c%" EQU "3" exit

goto :choice

:verify1

IF EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response1

goto :backup

:response1

echo.

echo.

echo You already have a "Folder View Settings Backup" folder on your desktop.

echo Please move it to another location, and try again.

echo.

pause

goto :choice

:backup

mkdir "%userprofile%\Desktop\Folder View Settings Backup"

REG EXPORT HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y

REG EXPORT HKCU\Software\Microsoft\Windows\Shell\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y

REG EXPORT HKCU\Software\Microsoft\Windows\Shell\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y

REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y

REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y

REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y

REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y

cls

echo.

echo Backup of folder view settings successfully completed.

echo.

pause

exit

:verify2

IF NOT EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response

goto :restore

:response

echo.

echo.

echo You do not have a "Folder View Settings Backup" folder on your desktop.

echo Please place the backup folder on your desktop, and try again.

echo.

pause

goto :choice

:restore

REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F

Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F

Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F

Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F

Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F

Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F

Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"

cls

echo.

echo Backup of folder view settings successfully restored.

echo.

echo Waiting to restart explorer to apply.

echo Your screen will flash as explorer is restarted.

echo.

echo.

pause

taskkill /f /im explorer.exe

start explorer.exe

exit

Puede copiar y pegar el texto anterior en la nota. A continuación, presione CTRL + S y guarde el archivo en su escritorio con la extensión .bat . Haga esto agregando .bat al final del nombre del archivo antes de presionar el botón Guardar .

crear archivo por lotes

Los archivos guardados en la extensión .bat son archivos por lotes y cuando se hacen correctamente, le permitirán ejecutar comandos en su sistema Windows. Obtenga más información sobre los archivos por lotes y explore estos fantásticos trucos .

Desbloquee el archivo .bat

Después de guardar con éxito el archivo recién creado como un archivo .bat , Windows puede bloquearlo. Para ejecutar este archivo, primero deberá desbloquearlo. Para hacer esto, haga clic derecho en el archivo y seleccione Propiedades en el menú contextual.

Cambie a la pestaña General de la ventana Propiedades y busque la casilla de verificación Desbloquear en la parte inferior de la ventana. Marque esta casilla y presione el botón Aceptar para desbloquear el archivo por lotes.

Si falta la casilla de verificación Desbloquear en su configuración, significa que Windows no bloqueó el archivo y puede pasar al siguiente paso.

Ejecute el archivo .bat

Después de desbloquear el archivo .bat, está listo para comenzar. Puede ejecutar el archivo .bat haciendo doble clic en él. Al ejecutar el archivo por lotes, se abre una ventana de símbolo del sistema que muestra las siguientes opciones:

Haga una copia de seguridad de la configuración de la vista de carpetas.

Restaurar la configuración de vista de carpeta desde la copia de seguridad.

Cancelar.

Para hacer una copia de seguridad de la configuración de vista de carpetas, presione 1 y presione la tecla ENTER. Si desea restaurar la configuración de vista de carpetas, presione 2 y presione ENTER.

Gracias por visitar este sitio, espero que te haya gustado y vuelvas proximamente, compartela en las redes sociales, gracias

Compartir en Facebook Compartir en twitter

Semrush sigue a tu competencia

Fecha actualización el 2020-12-04. Fecha publicación el 2020-12-04. Categoría: windows 10 Autor: Oscar olg Mapa del sitio Fuente: lifehacker